@echo off
    TITLE Quick copy from PC text to As400 source member
    cd \
    echo TOSOURCE.bat
    echo    Quick copy from PC text to As400 source member.
    echo    .
    echo    Copia veloce da un un file txt su PC a un membro sorgente As400.
    echo    .
    echo    Claudio Neroni 24-11-2008 Creato.
    echo    .
rem      <...+....1....+....2....+....3....+....4....+....5....+....6....+....7....+....>
    echo    ATTENZIONE: l'estensione del presente file DEVE ESSERE ".bat".
    echo    Il nome completo del file PC puo' essere fornito trascinando l'icona 
    echo    del file PC sopra l'icona del presente ".bat".
    echo    Il nome del file PC di tipo txt, datore del contenuto al membro sorgente, 
    echo    viene acquisito nel primo parametro di chiamata %%1 tramite trascinamento.
    echo    File PC e membro sorgente sono omonimi tra loro.
    echo    Per poter usare tale tecnica, sull'As400 "ASSYSTEM" deve esistere
    echo    il file sorgente ricevente "TOASFILE" con lunghezza record 112
    echo    nella libreria richiesta "TOASLIBRARY".
    echo    Un eventuale membro source preesistente viene ricoperto.
    echo    .
    echo    I parametri di accesso all'As400
    echo    "ASSYSTEM", "MYUSER" e "MYPASSWORD" 
    echo    si possono cablare per chiarezza e semplicita' 
    echo    ma per impostarli e' consigliabile fare uso di un altro ".bat"
    echo    (ad esempio ACCESSO400.bat), contenente le specifiche di settaggio.
    echo    .
    echo    Anche i parametri di personalizzazione della procedura
    echo    "TOASFILE" e "TOASLIBRARY" 
    echo    sono gestiti nello stesso file di settaggio.
    echo    .
    set msg=Perche' funzioni, occorre trascinare il file scatenante sul presente bat!  
    @if .%1==. @echo ERRORE! && @echo %msg% && @pause && GOTO ENDPGM
rem Annota Parametri di accesso.
rem    set assystem=ASSYSTEM
rem    set myuser=MYUSER
rem    set mypassword=MYPASSWORD
rem Imposta file e libreria che contengono il membro sorgente da scaricare su PC.
rem    set toasfile=TOASFILE
rem    set toaslibrary=TOASLIBRARY
rem Chiama batch alternativo alle precedenti specifiche di settaggio.
    call J:\ACCESSO400.bat
rem Imposta l'indirizzario di lavoro.
    set work=WORK
rem Imposta un nome di lavoro.
    set workname=TOSOURCE
rem Crea l'indirizzario di lavoro sul disco di lavoro.
    md C:\%WORK%
rem Ricava in file il nome completo del file.
    set file=%1
rem Ricava in filen il nome del file senza percorso e senza estensione.
    set filename=%~n1
rem Compone il nome del work file che conterra' le istruzioni ftp da eseguire.
    set workftp=C:\%WORK%\%workname%.ftp
rem Scrive le istruzioni da eseguire con ftp.
rem Utente.
    echo %myuser%>%WORKFTP%
rem Password.
    echo %mypassword%>>%WORKFTP%
rem Copia da file PC a membro sorgente As400.
    echo put %file% "/qsys.lib/%toaslibrary%.lib/%toasfile%.file/%filename%.mbr">>%WORKFTP%
rem Abbandona ftp.
    echo quit>>%WORKFTP%
rem Chiama ftp per eseguire le istruzioni scritte nel file.
    ftp -s:%WORKFTP% %assystem%
    pause Si ferma per permettere l'esame del log prima che si chiuda la finestra comandi.
rem Cancella transito.
    del %WORKFTP%
:ENDPGM